ESP32 自動澆水系統教學：土壤感測器 V2.0 + 繼電器完整接線與程式範例

				
					
#include <SimpleDHT.h>
#include "Wire.h"
#include "U8g2lib.h"  //OLED 螢幕解析度為128*64

const int Light = 36;     //光敏電阻腳位36，變數為＂Light"
const int LED = 2;        //LED燈內建腳位2，變數為"LED"
const int pinDHT11 = 16;  //DHT11溫度感測器腳位16，變數為"pinDHT11"
const int dry = 3000;     //土壤濕度感測到乾燥值為3000
const int wet = 1165;     //土壤濕度感測到濕度值為1165
const int relay = 5;      //繼電器腳位5，變數為＂relay＂W

SimpleDHT11 dht11(pinDHT11);
U8G2_SSD1306_128X64_NONAME_F_HW_I2C u8g2(U8G2_R0, /* reset=*/U8X8_PIN_NONE);


void setup() {
  Serial.begin(115200);
  pinMode(LED, OUTPUT);    //設定LED作為輸出
  pinMode(Light, INPUT);   //Light作為輸入
  pinMode(relay, OUTPUT);  //relay作為輸出

  u8g2.begin();                                //初始化
  u8g2.enableUTF8Print();                      //啟用 UTF8字集
  u8g2.setFont(u8g2_font_unifont_t_chinese1);  //設定使用中文字形
  u8g2.setDrawColor(1);                        //設定顏色，我們是單色只有1
  u8g2.setFontPosTop();                        //座標從上開始
  u8g2.setFontDirection(0);                    //0不旋轉、1->90、2->180、3->270
  pinMode(32, OUTPUT);
}

void loop() {
  byte temperature = 0;
  byte humidity = 0;
  int err = SimpleDHTErrSuccess;
  if ((err = dht11.read(&temperature, &humidity, NULL)) != SimpleDHTErrSuccess) {
    Serial.print("Read DHT11 failed, err=");
    Serial.print(SimpleDHTErrCode(err));
    Serial.print(",");
    Serial.println(SimpleDHTErrDuration(err));
    delay(1000);
    return;
  }

  int LightValue;                  //宣告整數變數"LightValue"
  LightValue = analogRead(Light);  //讀取Light的數值放在LightValue
  Serial.println(LightValue);      //LightValue顯示在序列視窗

  if (LightValue < 600) {  //如果LightValue值小於600時，LED就開啟，否則LED是關閉的
    digitalWrite(LED, HIGH);
  } else {
    digitalWrite(LED, LOW);
  }

  int sensorVal = analogRead(4);                              //土壤感測器腳位4，變數為sensorVal
  int percentageHumididy = map(sensorVal, wet, dry, 100, 0);  //將感測值比值成1~100%
  if (sensorVal > 3000) {                                     //如果土壤感測器值大於3000時，啟動繼電器，讓水泵澆水
    digitalWrite(relay, HIGH);
    delay(20000);  //澆水20秒
  } else {         //否則繼電器是關閉的
    digitalWrite(relay, LOW);
  }

  Serial.print(percentageHumididy);
  Serial.println("%");

  u8g2.clearBuffer();    //顯示前清除螢幕
  u8g2.setCursor(0, 5);  //移動游標
  u8g2.print("溫濕度:");
  u8g2.print((int)temperature + String("*C"));  //寫入文字
  u8g2.print(String("/"));
  u8g2.print((int)humidity + String("%"));  //寫入文字

  u8g2.setCursor(0, 25);  //移動游標
  u8g2.print("土壤濕度:");
  u8g2.print((int)percentageHumididy + String("%"));  //寫入文字

  u8g2.setCursor(0, 45);   //移動游標
  u8g2.print("亮度:");     //寫入文字
  u8g2.print(LightValue);  //寫入文字

  u8g2.sendBuffer();  //送到螢幕顯示

  delay(100);  //每0.1秒感測一次
}